home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Diamond Collection
/
The Diamond Collection (Software Vault)(Digital Impact).ISO
/
cdr37
/
regreq.zip
/
REGREQ.PPS
< prev
next >
Wrap
Text File
|
1995-03-20
|
4KB
|
121 lines
;------------------------------------------------------------------------
; REGREQ.PPE v1.0
; Copyright 1995 - Herbert Bushong
;------------------------------------------------------------------------
; A New user log-in PPE for closed boards to allow a new user to
; Download an access request file before logging them off.
; This PPE is used in a security specific display file for a demo
; account that has been set up for this purpose.
; Uses a config file to supply necessary information
*$USEFUNCS
*$INCLUDE:d:\pcb\ppl\libs\miscfn.lib
BEGIN
STRING CfgFile, RRIntroFile, RRDLFile, TempIn
STRING DLCmd, DLProt
STRING MsgTemp, MsgPriv, MsgFrom, MsgTo, MsgConf, MsgSubject
STRING RRName, RRStreet1, RRStreet2, RRCity, RRState, RRZip, RRCountry
INTEGER fh1
CfgFile=PPEPATH()+PPENAME()+".CFG"
MsgTemp=PPEPATH()+"RRTMPMSG.$$$"
MsgFrom="SYSTEM DAEMON"
MsgSubject=PPEName()+": notice"
DLCmd="D;"+RRDLFile
DLProt="Z"
;READ CONFIG FILE
fopen fh1, CfgFile, O_RD,S_DN
if (FERR(fh1)) THEN
LOG FALSE, "Error opening "+CfgFile
PRINTLN "An Error Occured. Please try back another time...."
GOTO finished
ENDIF
RRIntroFile=GetCfgLine(fh1)
RRDLFile=GetCfgLine(fh1)
MsgTo=GetCfgLine(fh1)
IF (MsgTo="") Let MsgTo="SYSOP"
MsgConf=GetCfgLine(fh1)
If (MsgConf="") LET MsgConf="0"
MsgPriv = UPPER(GetCfgLine(fh1))
If ((MsgPriv<>"N")&&(MsgPriv<>"R")) Let MsgPriv="R"
FCLOSE fh1
;ASK IF THEY WANT TO DL Reg. Request File
CLS
DISPFILE RRIntroFile, GRAPH+LANG
NEWLINE
TempIn="Y"
INPUTYN "Would you like to download the Access Request File",TempIn,@X0A
TempIn=UPPER(TempIn)
NEWLINE
IF (TempIn=NoChar()) Goto AskMail
InputStr "Please provide your Real Name",RRName,@X0A,45,MASK_ALPHA(),LFAFTER+FIELDLEN
NewLine
PrintLN "@X0BChoose a Transfer Protocol"
InputStr "(X)-modem, (Y)-Modem, or (Z)-modem",DLProt,@X0B,1,"xzyXYZ",LFAFTER+FIELDLEN
DLCmd=DLCmd+";"+DLProt
COMMAND FALSE,DLCmd
fh1=FNEXT()
FCREATE fh1,MsgTemp,O_WR,S_DB
FPUTLN fh1, RRName
FPUTLN fh1, "has downloaded the Request Registration File."
FCLOSE fh1
GOTO SendMessage
:AskMail
TempIn="Y"
INPUTYN "Would you like to an application Mailed to you",TempIn,@X0A
TempIn=UPPER(TempIn)
NEWLINE
IF (TempIn=NoChar()) Goto Finished
CLS
PRINTLN "@X0APlease Provide the Following Information@X07"
Newlines 2
TempIn=""
PROMPTSTR 259, TempIn, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
RRName=TempIn
TempIn=""
PROMPTSTR 260, TempIn, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
RRName=RRName+TempIn
DISPTEXT 698, NEWLINE
PROMPTSTR 699, RRStreet1, 50,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 700, RRStreet2, 50,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 701, RRCity, 25,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 702, RRState,10,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 703, RRZip, 10,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
PROMPTSTR 704, RRCountry, 15,MASK_ALPHA(),FIELDLEN+GUIDE+LFAFTER
fh1=FNEXT()
FCREATE fh1,MsgTemp,O_WR,S_DB
FPUTLN fh1, RRName
FPUTLN fh1, "has requested you mail the Request Registration Form."
FPUTLN fh1, "The following address info was provided:"
FPUTLN fh1, ""
FPUTLN fh1, RRName
FPUTLN fh1, RRStreet1
if (TRIM(RRStreet2," ")<>"") FPUTLN fh1, RRStreet2
FPUTLN fh1, TRIM(RRCity," ")+", "+RRState+" "+RRZip
FPUTLN fh1, RRCountry
FCLOSE fh1
:SendMessage
NEWLINES 2
PRINTLN "@X0DSending Message to Sysop@X07"
MESSAGE S2I(MsgConf,"10"), MsgTo, MsgFrom, MsgSubject, MsgPriv, 0, FALSE, FALSE, MsgTemp
CLS
PRINTLN "@X0AThank you..."
PRINTLN "Now Logging off...@X07"
:Finished
BYE
END